Aminet 21/Aminet 21 (1997)(GTI - Schatztruhe)[!][Oct 1997].iso/Aminet/biz/swood/FW_Font_eng.lha/FW_Font-e/FontLook.fw.long

Text File | 1997-08-07 | 4.9 KB | 208 lines

/* Here you get an overview about your fonts
 © Heiko Schröder / 08/07/97 / Mail: [e-mail]*/

Address='FinalW'
Options results

STATUS PORTNAME
FW = result
address = FW

SIGNAL ON BREAK_C

'ShowMessage 2 0 "FontLook V2.80" "for individual fonts..." "(©) Heiko Schröder - 08/07/97" ":-)" "Ok" "(-:"'
'ShowMessage 1 1 "A T T E N T I O N !" "The macro needs an empty document!" "Clear the document?" "Yes" "Abort" ""'
if result=2 then call BREAK_C
Cleardoc Force

'ShowMessage 2 0 "codes or layout" "" "" "codes" "layout" ""'
cl=result

'ShowMessage 2 0 "Screen output?" "" "" "normal" "speed" ""'
ba=result

'ShowMessage 1 0 "Do you need perforation signs?" "" "" "Yes" "No" ""'
lm=result

/*minimize Window*/
IF ba=2 THEN DO
   status WINDOW
   parse VAR result links oben breite hoehe minbreite minhoehe .
   sizewindow minbreite minhoehe
End

GetDocItemPrefs Decimal
Punkt=Result
If Punkt="Comma" then DocItemPrefs Decimal Period

Font
a=RC

If a=0 then do
   Type d2c(32)
   BackSpace
   status FontPath
   FullFontName=result
   status FontName
   ShortFontName=result

   IF ba=2 THEN View 20

   Pagesetup Pagetype A4 Orient Tall Pages RightOnly Top 0 Bottom 2.54 Left 0 Right 0
   SectionSetup Top 2.54 Bottom 2.54 Inside 2 Outside 1

   GraphicTool
   LinePrefs LineWt .5
   DrawLine 1 2 3.5 20 3.5
   DrawLine 1 2 26 20 26

   If lm=1 then DrawLine 1 .5 14.85 1 14.85

   TextTool
   If cl=1 then do

      Do i=0 to 13
         SetTab i*1.3+0.8 Right
      End

      Justify Center
      Font Softsans
      FontSize 18
      Type ShortFontName; NewParagraph; NewParagraph

      DO a = 33 BY 14 FOR 16

         Font Softsans
         FontSize 8
         zeile = ""
         DO x = a TO a + 13 WHILE x < 256
            zeile = zeile || d2c( 9 ) || x || d2c( 32 ) || d2c( x )
         END

         If x = 256 then zeile = zeile || d2c( 9 )
         Type zeile; NewParagraph

         Font ShortFontName
         FontSize 24
         zeile = ""
         DO x = a TO a + 13 WHILE x < 256
            zeile = zeile || d2c( 9 ) || d2c( x )
         END

         If x = 256 then zeile = zeile || d2c( 9 )
         Type zeile; NewParagraph
      END

      FontSize 12
      Type d2c(9); NewParagraph
      Font Softsans

      FontSize 8
      Justify Right
      Type Date(O)" - "FullFontName

   END

/* --------- */

   If cl=2 then do

      Justify Center
      Font Softsans
      FontSize 18
      Type ShortFontName; NewParagraph

      Justify Left
      Font FullFontName
      FontSize 8
      NewParagraph; Type "This is 8-point type - not easy to read!"; NewParagraph

      FontSize 9
      Type "9-point type is about the smallest readable size."; NewParagraph /* MiK */

      FontSize 10
      Type "With 10-point type, we have a normal text size."; NewParagraph /* MiK */

      FontSize 12
      Type "With some fonts, 12-point type is easier to read."; NewParagraph /* MiK */

      FontSize 14
      Type "14-point type is good for subheadings."; NewParagraph /* MiK */

      FontSize 16
      Type "For larger subheadings, try 16-point type."; NewParagraph /* MiK */

      FontSize 18
      Type "18-point type makes nice small headlines."; NewParagraph /* MiK */

      FontSize 24
      Type "24-point type is for medium headlines."; NewParagraph /* MiK */

      FontSize 36
      Type "36-point is for larger ones."; NewParagraph /* MiK */

      FontSize 48
      Type "48-point almost shouts!"; NewParagraph /* MiK */

      FontSize 60 /* MiK */
      Type "60-point is huge!"; NewParagraph /* MiK */

      FontSize 12
      Font SoftSans
      Type d2c( 32 ); NewParagraph /* MiK */
      NewParagraph; Type "NORMAL"; NewParagraph /* MiK */

      FontSize 10
      Font ShortFontName
      Type "ABCDEFGHIJKLMNOPQRSTUVWXYZ"; NewParagraph
      Type "abcdefghijklmnopqrstuvwxyz 1234567890 !@#$%^&*()-+=[]{}/:;,.?"; NewParagraph
      Type "The quick brown fox jumps over the lazy dog."; NewParagraph; NewParagraph; NewParagraph

      FontSize 12
      Font SoftSans
      Type "EXTENDED CHARACTERS"; NewParagraph

      FontSize 10
      Font FullFontName
      DO j = 128 BY 32 FOR 4 /* MiK */
         Type XRange( d2c( j ), d2c( j + 31 ) ); NewParagraph /* MiK */
      End
      Status BodyTextHeight
      th=result
      FG=26.24-2.113-th
      FG=Trunc(FG*8/0.34)
      FontSize FG
      Type d2c(9)
      Font SoftSans
      FontSize 8
      Type R
      Justify Right
      Type Date(O)" - "FullFontName
   End

   call WH

   'ShowMessage 2 1 "Whats next?" "" "" "save" "print" "abort"'
   If result=1 then Save
   If result=2 then Print
END

'ShowMessage 2 0 "Thanks for using." "" "" "@-`-" "Please" ":-))"'
'ShowMessage 2 1 "© Heiko Schröder" "email: [e-mail]" "http://yi.com/home/SchroederHeiko" "Okay" "Yes" ":-))"'

EXIT

BREAK_C:
   'ShowMessage 1 1 "Macro aborted..." "" "" "I know..." "" ""'
   call WH
   EXIT

WH:
   If ba=2 then do
      View
      Redraw
      sizewindow breite hoehe
   End
   If Punkt="Comma" then DocItemPrefs DECIMAL Comma
Return